1. 簡介
在本程式碼研究室中，我們列出從 ABAP 環境使用 ABAP SDK for Google Cloud 呼叫 Google Cloud Vertex AI 的 PaLM 2 Text (text-bison) 基礎模型的步驟。
本程式碼研究室會使用下列 Google Cloud 服務：
- Vertex AI
- Cloud Shell
建構項目
您將建立下列項目：
- 在 Google Cloud 專案中啟用 Vertex AI API。
- 將提示傳送至 Vertex AI 的 PaLM 2 Text 模型，並使用 ABAP SDK for Google Cloud 接收回覆。
2. 需求條件
- 瀏覽器，例如 Chrome 或 Firefox。
- 啟用計費功能的 Google Cloud 專案，或建立 Google Cloud Platform 90 天免費試用帳戶。
- 系統中已安裝 SAP GUI (Windows 或 Java)。如果筆電上已安裝 SAP GUI，請使用 VM 外部 IP 位址做為應用程式伺服器 IP，連線至 SAP。如果您使用 Mac，也可以安裝這個連結提供的 SAP GUI for Java。
3. 事前準備
- 您已在系統上安裝 ABAP SDK for Google Cloud。如要設定新系統，請參閱程式碼研究室 - 在 Google Cloud Platform 上安裝 ABAP Platform Trial 1909，並安裝 ABAP SDK。
- 您將使用 Cloud Shell，這是 Google Cloud 中執行的指令列環境。在 Cloud Shell 中，按一下右上角的「啟用 Cloud Shell」：
- 執行下列指令，驗證帳戶並將預設專案設為
abap-sdk-poc。以區域us-west4-b為例。如有需要，請根據偏好設定，在下列指令中變更專案和區域。
gcloud auth login
gcloud config set project abap-sdk-poc
gcloud config set compute/zone us-west4-b
4. 總覽
以下簡要說明您在本程式碼研究室中會使用的部分 Vertex AI 實體：
- 文字專用的 PaLM 2：文字專用的 PaLM 2 (text-bison、text-unicorn) 基礎模型經過最佳化，可執行各種自然語言工作，例如情緒分析、實體擷取和內容建立。
- Text-bison：這是 Google AI 開發的大型語言模型 (LLM)。這類模型是生成式 AI 的基礎模型，可理解及生成語言。
5. 在 Google Cloud 專案中啟用 Vertex AI
- 前往 Google Cloud 專案，然後按一下右上角的「啟用 Cloud Shell」。
- 啟動殼層後，請執行下列指令，在 Google Cloud 專案中啟用 Cloud Secret Manager API。
gcloud services enable aiplatform.googleapis.com
現在您應該已在 Google Cloud 專案中啟用 Vertex AI API。
6. 建立具有使用者角色的服務帳戶
如要建立具備必要角色的服務帳戶，請完成下列步驟：
- 在 Cloud Shell 終端機中執行下列指令：
gcloud iam service-accounts create abap-sdk-vertexai-tester \
--display-name="Service Account for Vertex AI"
- 現在，請將必要角色新增至上一步建立的服務帳戶，以便存取 API。
gcloud endpoints services add-iam-policy-binding aiplatform.googleapis.com \ --member='serviceAccount:abap-sdk-vertexai-tester@abap-sdk-poc.iam.gserviceaccount.com' \
--role='roles/roles/aiplatform.endpoints.predict'
上述指令會使用 abap-sdk-poc 做為 Google Cloud 專案的範本名稱。並將其替換為專案 ID。
- 如要確認角色已新增，請前往「IAM」IAM頁面。您建立的服務帳戶應會列出，以及已指派給該帳戶的角色。
7. 在 SAP 中建立 SDK 設定
Google Cloud 端的必要條件設定完成後，我們就可以繼續進行 SAP 端的設定。如需驗證和連線相關設定，Google Cloud 的 ABAP SDK 會使用 /GOOG/CLIENT_KEY 和 /GOOG/SERVIC_MAP 表格。
如要在 /GOOG/CLIENT_KEY 表格中維護設定，請執行下列步驟：
- 在 SAP GUI 中輸入交易代碼 SPRO。
- 按一下「SAP Reference IMG」。
- 依序點選「ABAP SDK for Google Cloud」>「Basic Settings」>「Configure Client Key」。
- 針對欄位保留下列值：
欄位 | 說明 |
Google Cloud 金鑰名稱 | VERTEX_AI_DEMO |
Google Cloud 服務帳戶名稱 | abap-sdk-vertexai-tester@abap-sdk-poc.iam.gserviceaccount.com |
Google Cloud 範圍 | https://www.googleapis.com/auth/cloud-platform |
Google Cloud 專案 ID | abap-sdk-poc |
授權類別 | /GOOG/CL_AUTH_GOOGLE |
將其他欄位留空
Vertex AI 有特定區域的端點，我們必須為端點建立 RFC 目的地，並根據用戶端金鑰，在資料表 /GOOG/SERVIC_MAP 中建立 API 的對應。(如需 Vertex AI 的區域專屬服務端點，請參閱這個 連結)。
以下是為程式碼研究室建立 RFC 的步驟。
- 前往交易代碼 SM59，建立「G」類型連線。
- 將目的地命名為「ZGOOG_VERTEXAI_V1」。
- 視需要提供說明，並將通訊埠設為「443」。
- 將「主機」地址設為「us-west4-aiplatform.googleapis.com」，因為我們在程式碼研究室中參照的是「us-west4-b」位置。
以下是 RFC 目的地螢幕截圖，供您參考。
如要維護 /GOOG/SERVIC_MAP 表格中的設定，請執行下列步驟：
- 在 SAP GUI 中輸入交易代碼 SPRO。
- 按一下「SAP Reference IMG」。
- 依序點選「ABAP SDK for Google Cloud」>「Basic Settings」>「Configure Service Mapping」。
- 針對欄位保留下列值：
欄位 | 說明 |
Google Cloud 金鑰名稱 | VERTEX_AI_DEMO |
Google 服務名稱 | aiplatform:v1 |
RFC 目的地 | ZGOOG_VERTEXAI_V1 |
8. 使用 SDK 呼叫 PaLM 2 Text
- 登入 SAP 系統。
- 前往交易代碼 SE38，然後建立名為「ZDEMO_VERTEX_AI」的報表。
- 在隨即開啟的彈出式視窗中，提供如下所示的詳細資料，然後按一下「儲存」。
在下一個彈出式視窗中，選取「本機物件」或提供適當的套件名稱。
- 在 ABAP 編輯器中，新增下列程式碼片段：
- 在這個程式碼片段中，我們將緊急訂單要求的電子郵件內容做為提示，並附上剖析指示，以便擷取訂單屬性，例如客戶姓名、公司名稱、客戶稱謂、項目名稱、訂購數量、運送地址和交貨日期。
- ABAP 型別宣告會準備要求，並根據這份文件擷取 Vertex AI PaLM 2 Text 模型的相關回應。
* Types declarations
TYPES:
BEGIN OF ty_instances,
content TYPE string,
END OF ty_instances.
TYPES:
tt_instances TYPE STANDARD TABLE OF ty_instances WITH DEFAULT KEY .
TYPES:
BEGIN OF ty_parameters,
max_output_tokens TYPE i,
temperature TYPE f,
top_k TYPE i,
top_p TYPE f,
END OF ty_parameters.
TYPES ty_categories TYPE string .
TYPES:
BEGIN OF ty_scores,
scores TYPE string,
END OF ty_scores .
TYPES:
tt_categories TYPE STANDARD TABLE OF ty_categories WITH DEFAULT KEY .
TYPES:
tt_scores TYPE STANDARD TABLE OF ty_scores WITH DEFAULT KEY .
TYPES:
BEGIN OF ty_safety_attributes,
blocked TYPE abap_bool,
categories TYPE tt_categories,
scores TYPE tt_scores,
END OF ty_safety_attributes .
TYPES:
BEGIN OF ty_predictions,
content TYPE string,
safety_attributes TYPE ty_safety_attributes,
END OF ty_predictions .
TYPES:
tt_predictions TYPE STANDARD TABLE OF ty_predictions WITH DEFAULT KEY .
TYPES:
BEGIN OF ty_output,
deployed_model_id TYPE string,
metadata TYPE REF TO data,
model TYPE string,
model_display_name TYPE string,
model_version_id TYPE string,
predictions TYPE tt_predictions,
END OF ty_output.
* Data declarations
DATA:
lv_p_projects_id TYPE string,
lv_p_locations_id TYPE string,
lv_p_publishers_id TYPE string,
lv_p_models_id TYPE string,
ls_input TYPE /goog/cl_aiplatform_v1=>ty_001.
DATA:
lv_email_text TYPE string.
CONSTANTS: lc_ob TYPE c VALUE '{',
lc_cb TYPE c VALUE '}'.
* Email content having order request
lv_email_text = |'Hello, We are running low on Dark Chocolates, please ship 20 units of "Lindt 90% Dark Chocolates"'| &&
|' and 10 units of "Toblerone Dark Bar 100g" to "Google Cloud, 1 East 2'| &&
|'4th St, Kearney NE" by as early as possible. Thanks and Regards, John Doe, Procurement Manager, Google Cloud'|.
TRY.
DATA(lv_raw) = VALUE string( ).
* Open HTTP Connection
DATA(lo_client) = NEW /goog/cl_aiplatform_v1( iv_key_name = 'VERTEX_AI_DEMO' ).
* Populate relevant parameters
lv_p_projects_id = lo_client->gv_project_id.
lv_p_locations_id = 'us-west4-b'.
lv_p_publishers_id = 'google'.
lv_p_models_id = 'text-bison'.
* Call API method: aiplatform.projects.locations.publishers.models.predict
CALL METHOD lo_client->predict_models
EXPORTING
iv_p_projects_id = lv_p_projects_id
iv_p_locations_id = lv_p_locations_id
iv_p_publishers_id = lv_p_publishers_id
iv_p_models_id = lv_p_models_id
is_input = VALUE #(
parameters = NEW ty_parameters(
max_output_tokens = 256
temperature = '0.2'
top_k = '40'
top_p = '0.8' )
* Pass the prompt with email content and instructions to get order attributes
instances = NEW tt_instances( ( content =
|'Give me the Customer Name, Company Name, Customer Designation, Item Name, Order Quantity, Shipping address, Delivery Date'| &&
|'from an email context. Structure the response in JSON camelcase format with fields corresponding to each entities. Place the ordered items in a JSON nest'| &&
|'Default the delivery date to a future date in DD.MM.YYYY format. Here is the email content:'| && lv_email_text ) ) )
IMPORTING
es_raw = lv_raw
ev_ret_code = DATA(lv_ret_code)
ev_err_text = DATA(lv_err_text)
es_err_resp = DATA(ls_err_resp).
IF lo_client->is_success( lv_ret_code ).
DATA(ls_output_llm) = VALUE ty_output( ).
* Deserializing API response to get model response
/goog/cl_json_util=>deserialize_json( EXPORTING iv_json = lv_raw
iv_pretty_name = /ui2/cl_json=>pretty_mode-extended
IMPORTING es_data = ls_output_llm ).
cl_demo_output=>new(
)->begin_section( 'API Call Successful:'
)->write_text( 'Respose from model:'
)->write_text( ls_output_llm-predictions[ 1 ]-content
)->display( ).
ELSE.
cl_demo_output=>new(
)->begin_section( 'API Call Unsuccessful:'
)->write_text( 'Error Message:'
)->write_text( lv_err_text
)->display( ).
ENDIF.
* Close HTTP Connection
lo_client->close( ).
CATCH /goog/cx_sdk INTO DATA(lo_exception).
DATA(lv_error) = lo_exception->get_text( ).
cl_demo_output=>new(
)->begin_section( 'Exception Occured:'
)->write_text( lv_error
)->display( ).
ENDTRY.
- 儲存並啟用報表程式。
- 執行報表 (F8)。
執行成功後，您應該會看到如下所示的報表輸出內容，其中包含按照提示擷取的訂單屬性。
9. 恭喜
恭喜！您已成功從 ABAP 程式呼叫 Vertex AI PaLM 2 Text 模型，並使用 ABAP SDK for Google Cloud 剖析訂單要求。
您也可以考慮使用 Google Cloud 的 ABAP SDK，從 Gmail 收件匣取得電子郵件內容，然後按照本程式碼研究室的說明，將內容傳遞至 Vertex AI，不必進行硬式編碼。
10. 清除所用資源
如不想繼續進行與 Google Cloud 適用的 ABAP SDK 相關的額外程式碼研究室，請繼續進行清理作業。
刪除專案
- 刪除 Google Cloud 專案：
gcloud projects delete abap-sdk-poc
刪除個別資源
- 刪除運算執行個體：
gcloud compute instances delete abap-trial-docker
- 刪除防火牆規則：
gcloud compute firewall-rules delete sapmachine
- 刪除服務帳戶：
gcloud iam service-accounts delete \
abap-sdk-dev@abap-sdk-poc.iam.gserviceaccount.com