Google Cloud के लिए ABAP SDK टूल की मदद से, अपने ABAP एनवायरमेंट से Vertex AI LLM को कॉल करना

1. परिचय

इस कोडलैब में, हमने Google Cloud के लिए ABAP SDK का इस्तेमाल करके, अपने ABAP एनवायरमेंट से Google Cloud Vertex AI के PaLM 2 टेक्स्ट (text-bison) फ़ाउंडेशन मॉडल को कॉल करने का तरीका बताया है.

इस कोडलैब में, Google Cloud की इन सेवाओं का इस्तेमाल किया गया है:

  • Vertex AI
  • Cloud Shell

आपको क्या बनाना है

आपको ये चीज़ें बनानी होंगी:

  • Google Cloud प्रोजेक्ट में Vertex AI API चालू करना.
  • Vertex AI के PaLM 2 टेक्स्ट मॉडल को प्रॉम्प्ट पास करें और Google Cloud के लिए ABAP SDK का इस्तेमाल करके जवाब पाएं.

2. ज़रूरी शर्तें

  • Chrome या Firefox जैसा कोई ब्राउज़र.
  • बिलिंग की सुविधा वाला Google Cloud प्रोजेक्ट या Google Cloud Platform के लिए 90 दिनों के मुफ़्त ट्रायल वाला खाता बनाएं.
  • आपके सिस्टम में SAP GUI (Windows या Java) इंस्टॉल हो. अगर आपके लैपटॉप पर SAP GUI पहले से इंस्टॉल है, तो ऐप्लिकेशन सर्वर आईपी के तौर पर, वर्चुअल मशीन (वीएम) के बाहरी आईपी पते का इस्तेमाल करके SAP से कनेक्ट करें. अगर आपके पास Mac है, तो इस लिंक पर जाकर, Java के लिए SAP GUI भी इंस्टॉल किया जा सकता है.

3. शुरू करने से पहले

6757b2fb50ddcc2d.png

  • अपने खाते की पुष्टि करने और डिफ़ॉल्ट प्रोजेक्ट को abap-sdk-poc पर सेट करने के लिए, ये कमांड चलाएं. उदाहरण के लिए, ज़ोन us-west4-b का इस्तेमाल किया गया है. अगर ज़रूरी हो, तो अपनी पसंद के हिसाब से नीचे दिए गए निर्देशों में प्रोजेक्ट और ज़ोन बदलें.
gcloud auth login
gcloud config set project abap-sdk-poc
gcloud config set compute/zone us-west4-b

4. खास जानकारी

यहां Vertex AI की कुछ इकाइयों के बारे में खास जानकारी दी गई है. इनका इस्तेमाल इस कोडलैब में किया जाएगा:

  • टेक्स्ट के लिए PaLM 2: टेक्स्ट के लिए PaLM 2 (text-bison, text-unicorn) फ़ाउंडेशन मॉडल, अलग-अलग तरह के नैचुरल लैंग्वेज टास्क के लिए ऑप्टिमाइज़ किए गए हैं. जैसे, सेंटिमेंट विश्लेषण, इकाई निकालना, और कॉन्टेंट बनाना.
  • Text-bison: Text-bison एक लार्ज लैंग्वेज मॉडल (एलएलएम) है, जिसे Google के एआई ने बनाया है. यह जनरेटिव एआई का बुनियादी मॉडल है, जो भाषा को समझ सकता है और जनरेट कर सकता है.

5. अपने Google Cloud प्रोजेक्ट में Vertex AI को चालू करना

  1. अपने Google Cloud प्रोजेक्ट पर जाएं और सबसे ऊपर दाएं कोने में, 'Cloud Shell चालू करें' पर क्लिक करें.

8d15f753321c53e6.png

  1. शेल चालू होने के बाद, अपने Google Cloud प्रोजेक्ट में Cloud Secret Manager एपीआई को चालू करने के लिए, नीचे दिया गया कमांड चलाएं.
gcloud services enable aiplatform.googleapis.com

अब आपके Google Cloud प्रोजेक्ट में Vertex AI API चालू हो जाना चाहिए.

6. उपयोगकर्ता की भूमिकाओं वाला सेवा खाता बनाना

ज़रूरी भूमिकाओं वाला सेवा खाता बनाने के लिए, यह तरीका अपनाएं:

  1. Cloud Shell टर्मिनल में यह कमांड चलाएं:
gcloud iam service-accounts create abap-sdk-vertexai-tester \
--display-name="Service Account for Vertex AI"
  1. अब एपीआई को ऐक्सेस करने के लिए, ऊपर दिए गए चरण में बनाए गए सेवा खाते में ज़रूरी भूमिका जोड़ें.
gcloud endpoints services add-iam-policy-binding aiplatform.googleapis.com \ --member='serviceAccount:abap-sdk-vertexai-tester@abap-sdk-poc.iam.gserviceaccount.com' \
--role='roles/roles/aiplatform.endpoints.predict'

ऊपर दिए गए निर्देश, Google Cloud प्रोजेक्ट के टेंप्लेट के नाम के तौर पर abap-sdk-poc का इस्तेमाल करते हैं. इसे अपने प्रोजेक्ट आईडी से बदलें.

  1. भूमिका जोड़ी गई है या नहीं, इसकी पुष्टि करने के लिए IAM पेज पर जाएं. आपने जो सेवा खाता बनाया है वह उस भूमिका के साथ दिखना चाहिए जो उसे असाइन की गई है.

7. SAP में SDK टूल के कॉन्फ़िगरेशन बनाना

Google Cloud की ओर से ज़रूरी शर्तें सेट अप करने के बाद, हम SAP की ओर से कॉन्फ़िगरेशन की प्रोसेस शुरू कर सकते हैं. पुष्टि करने और कनेक्टिविटी से जुड़े कॉन्फ़िगरेशन के लिए, Google Cloud के लिए ABAP SDK, टेबल /GOOG/CLIENT_KEY और /GOOG/SERVIC_MAP का इस्तेमाल करता है.

टेबल /GOOG/CLIENT_KEY टेबल में कॉन्फ़िगरेशन को बनाए रखने के लिए, यह तरीका अपनाएं:

  1. SAP GUI में, ट्रांज़ैक्शन कोड SPRO डालें.
  2. SAP रेफ़रंस IMG पर क्लिक करें.
  3. Google Cloud के लिए ABAP SDK टूल > बुनियादी सेटिंग > क्लाइंट पासकोड कॉन्फ़िगर करें पर क्लिक करें.
  4. फ़ील्ड के लिए ये वैल्यू बनाए रखें:

फ़ील्ड

ब्यौरा

Google Cloud की कुंजी का नाम

VERTEX_AI_DEMO

Google Cloud सेवा खाते का नाम

abap-sdk-vertexai-tester@abap-sdk-poc.iam.gserviceaccount.com

Google Cloud का दायरा

https://www.googleapis.com/auth/cloud-platform

Google Cloud प्रोजेक्ट आइडेंटिफ़ायर

abap-sdk-poc

अनुमति की कैटगरी

/GOOG/CL_AUTH_GOOGLE

अन्य फ़ील्ड खाली छोड़ें

Vertex AI में क्षेत्र के हिसाब से एंडपॉइंट होते हैं. इसलिए, हमें एंडपॉइंट के लिए आरएफ़सी डेस्टिनेशन बनाना होगा और क्लाइंट पासकोड के हिसाब से टेबल /GOOG/SERVIC_MAP में एपीआई के लिए मैपिंग बनानी होगी. (Vertex AI के लिए, क्षेत्र के हिसाब से सेवा के एंडपॉइंट के बारे में जानने के लिए, यह लिंक देखें).

कोडलैब के लिए आरएफ़सी बनाने का तरीका यहां बताया गया है.

  • लेन-देन कोड SM59 पर जाएं और टाइप "G" कनेक्शन बनाएं.
  • डेस्टिनेशन का नाम "ZGOOG_VERTEXAI_V1" रखें.
  • ज़रूरत के मुताबिक जानकारी दें और पोर्ट के तौर पर "443" डालें.
  • "होस्ट" का पता " us-west4-aiplatform.googleapis.com" के तौर पर डालें, क्योंकि हम कोडलैब में "us-west4-b" लोकेशन का रेफ़रंस दे रहे हैं.

आपके रेफ़रंस के लिए, आरएफ़सी डेस्टिनेशन का स्क्रीनशॉट यहां दिया गया है.

54316c5de58624c7.png

टेबल /GOOG/SERVIC_MAP टेबल में कॉन्फ़िगरेशन को बनाए रखने के लिए, यह तरीका अपनाएं:

  1. SAP GUI में, ट्रांज़ैक्शन कोड SPRO डालें.
  2. SAP रेफ़रंस IMG पर क्लिक करें.
  3. Google Cloud के लिए ABAP SDK टूल > बुनियादी सेटिंग > सेवा मैपिंग कॉन्फ़िगर करें पर क्लिक करें.
  4. फ़ील्ड के लिए ये वैल्यू बनाए रखें:

फ़ील्ड

ब्यौरा

Google Cloud की कुंजी का नाम

VERTEX_AI_DEMO

Google की सेवा का नाम

aiplatform:v1

आरएफ़सी डेस्टिनेशन

ZGOOG_VERTEXAI_V1

8. SDK टूल का इस्तेमाल करके, PaLM 2 Text को चालू करना

  1. अपने SAP सिस्टम में लॉग इन करें.
  2. लेन-देन कोड SE38 पर जाएं और "ZDEMO_VERTEX_AI" नाम से रिपोर्ट बनाएं.
  3. इसके बाद, खुलने वाले पॉप-अप में नीचे दी गई जानकारी दें और सेव करें पर क्लिक करें.

b06fda1a879290f7.png

अगले पॉप-अप में, लोकल ऑब्जेक्ट चुनें या पैकेज का नाम डालें.

  1. ABAP एडिटर में, यह कोड स्निपेट जोड़ें:
  • इस स्निपेट में, हम ईमेल के कॉन्टेंट को प्रॉम्प्ट के तौर पर, ऑर्डर के लिए किए गए ज़रूरी अनुरोध के साथ पास कर रहे हैं. साथ ही, ऑर्डर के एट्रिब्यूट को निकालने के लिए, उसे पार्स करने के निर्देश भी दे रहे हैं. जैसे, ग्राहक का नाम, कंपनी का नाम, ग्राहक की पदवी, आइटम का नाम, ऑर्डर की संख्या, शिपिंग का पता, और डिलीवरी की तारीख.
  • ABAP टाइप के एलान, Vertex AI PaLM 2 टेक्स्ट मॉडल से अनुरोध तैयार करने और उसके जवाब को कैप्चर करने के लिए हैं. इसके बारे में ज़्यादा जानकारी के लिए, यहां दिए गए दस्तावेज़ देखें.
* Types declarations
TYPES:
  BEGIN OF ty_instances,
    content TYPE string,
  END OF ty_instances.

TYPES:
     tt_instances TYPE STANDARD TABLE OF ty_instances WITH DEFAULT KEY .

TYPES:
  BEGIN OF ty_parameters,
    max_output_tokens TYPE i,
    temperature       TYPE f,
    top_k             TYPE i,
    top_p             TYPE f,
  END OF ty_parameters.

TYPES ty_categories TYPE string .
TYPES:
  BEGIN OF ty_scores,
    scores TYPE string,
  END OF ty_scores .
TYPES:
  tt_categories TYPE STANDARD TABLE OF ty_categories WITH DEFAULT KEY .
TYPES:
  tt_scores TYPE STANDARD TABLE OF ty_scores WITH DEFAULT KEY .

TYPES:
  BEGIN OF ty_safety_attributes,
    blocked    TYPE abap_bool,
    categories TYPE tt_categories,
    scores     TYPE tt_scores,
  END OF ty_safety_attributes .

TYPES:
  BEGIN OF ty_predictions,
    content           TYPE string,
    safety_attributes TYPE ty_safety_attributes,
  END OF ty_predictions .
TYPES:
  tt_predictions TYPE STANDARD TABLE OF ty_predictions WITH DEFAULT KEY .

TYPES:
  BEGIN OF ty_output,
    deployed_model_id  TYPE string,
    metadata           TYPE REF TO data,
    model              TYPE string,
    model_display_name TYPE string,
    model_version_id   TYPE string,
    predictions        TYPE tt_predictions,
  END OF ty_output.

* Data declarations
DATA:
  lv_p_projects_id   TYPE string,
  lv_p_locations_id  TYPE string,
  lv_p_publishers_id TYPE string,
  lv_p_models_id     TYPE string,
  ls_input           TYPE /goog/cl_aiplatform_v1=>ty_001.

DATA:
      lv_email_text TYPE string.

CONSTANTS: lc_ob TYPE c VALUE '{',
           lc_cb TYPE c VALUE '}'.

* Email content having order request
lv_email_text = |'Hello, We are running low on Dark Chocolates, please ship 20 units of "Lindt 90% Dark Chocolates"'| &&
                |' and 10 units of "Toblerone Dark Bar 100g" to "Google Cloud, 1 East 2'| &&
                |'4th St, Kearney NE" by as early as possible. Thanks and Regards, John Doe, Procurement Manager, Google Cloud'|.

TRY.
    DATA(lv_raw) = VALUE string( ).
* Open HTTP Connection
    DATA(lo_client) = NEW /goog/cl_aiplatform_v1( iv_key_name = 'VERTEX_AI_DEMO' ).

* Populate relevant parameters
    lv_p_projects_id = lo_client->gv_project_id.
    lv_p_locations_id = 'us-west4-b'.
    lv_p_publishers_id = 'google'.
    lv_p_models_id = 'text-bison'.

* Call API method: aiplatform.projects.locations.publishers.models.predict
    CALL METHOD lo_client->predict_models
      EXPORTING
        iv_p_projects_id   = lv_p_projects_id
        iv_p_locations_id  = lv_p_locations_id
        iv_p_publishers_id = lv_p_publishers_id
        iv_p_models_id     = lv_p_models_id
        is_input           = VALUE #(
     parameters = NEW ty_parameters(
           max_output_tokens  = 256
           temperature = '0.2'
           top_k = '40'
           top_p  = '0.8' )
* Pass the prompt with email content and instructions to get order attributes
     instances = NEW tt_instances( ( content =
      |'Give me the Customer Name, Company Name, Customer Designation, Item Name, Order Quantity, Shipping address, Delivery Date'| &&
      |'from an email context. Structure the response in JSON camelcase format with fields corresponding to each entities. Place the ordered items in a JSON nest'| &&
      |'Default the delivery date to a future date in DD.MM.YYYY format. Here is the email content:'| && lv_email_text ) ) )
      IMPORTING
        es_raw             = lv_raw
        ev_ret_code        = DATA(lv_ret_code)
        ev_err_text        = DATA(lv_err_text)
        es_err_resp        = DATA(ls_err_resp).

    IF lo_client->is_success( lv_ret_code ).
      DATA(ls_output_llm) = VALUE ty_output( ).
* Deserializing API response to get model response
      /goog/cl_json_util=>deserialize_json( EXPORTING iv_json        = lv_raw
                                                      iv_pretty_name = /ui2/cl_json=>pretty_mode-extended
                                            IMPORTING es_data        = ls_output_llm ).
      cl_demo_output=>new(
        )->begin_section( 'API Call Successful:'
        )->write_text( 'Respose from model:'
        )->write_text( ls_output_llm-predictions[ 1 ]-content
        )->display( ).
    ELSE.
      cl_demo_output=>new(
        )->begin_section( 'API Call Unsuccessful:'
        )->write_text( 'Error Message:'
        )->write_text( lv_err_text
        )->display( ).

    ENDIF.

* Close HTTP Connection
    lo_client->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    DATA(lv_error) = lo_exception->get_text( ).
    cl_demo_output=>new(
     )->begin_section( 'Exception Occured:'
     )->write_text( lv_error
     )->display( ).

ENDTRY.
  1. रिपोर्ट प्रोग्राम को सेव और चालू करें.
  2. रिपोर्ट को लागू करें (F8).

एक्सपोर्ट पूरा होने पर, आपको प्रॉम्प्ट में दिए गए निर्देशों के मुताबिक, ऑर्डर के निकाले गए एट्रिब्यूट के साथ रिपोर्ट का आउटपुट नीचे दिखाया गया है.

c40839b43b8ac44f.png

9. बधाई हो

बधाई हो! आपने Google Cloud के लिए ABAP SDK का इस्तेमाल करके, ऑर्डर के अनुरोध को पार्स करने के लिए, अपने ABAP प्रोग्राम से Vertex AI PaLM 2 टेक्स्ट मॉडल को कॉल किया है.

हार्ड कोडिंग के बजाय, Google Cloud के लिए ABAP SDK का इस्तेमाल करके, अपने Gmail इनबॉक्स से ईमेल का कॉन्टेंट पाने के बारे में भी सोचा जा सकता है. इसके बाद, इस कोडलैब में बताए गए तरीके से कॉन्टेंट को Vertex AI में भेजा जा सकता है.

10. व्यवस्थित करें

अगर आपको Google Cloud के लिए ABAP SDK टूल से जुड़े अन्य कोडलैब जारी नहीं रखने हैं, तो कृपया क्लीनअप की प्रक्रिया शुरू करें.

प्रोजेक्ट मिटाना

  • Google Cloud प्रोजेक्ट मिटाएं:
gcloud projects delete abap-sdk-poc

अलग-अलग संसाधन मिटाना

  1. कंप्यूट इंस्टेंस मिटाने के लिए:
gcloud compute instances delete abap-trial-docker
  1. फ़ायरवॉल के नियम मिटाएं:
gcloud compute firewall-rules delete sapmachine
  1. सेवा खाता मिटाने के लिए:
gcloud iam service-accounts delete \
    abap-sdk-dev@abap-sdk-poc.iam.gserviceaccount.com