在執行 PSA 的現有 Cloud SQL 執行個體上啟用 Private Service Connect (Terraform)

1. 總覽

您可以透過多種方式，從其他專案或 VPC 網路連線至私人 Cloud SQL 執行個體。您可以使用私人服務存取權 (PSA)，透過私人連線存取 Google 和第三方服務的內部 IP 位址。如要擴充資料庫的存取權，您現在也可以啟用 Private Service Connect (PSC)。

Private Service Connect (PSC) 可讓服務供應商透過服務連結公開服務，讓使用者在其環境中建立 PSC 端點和/或 PSC 後端。透過這些 PSC 端點，他們可以透過使用者指定的私人 IP 連線至供應者服務。

在本研究室中，您可以設定及測試該選項。

注意：這個解決方案有一些限制，您可以在說明文件的「Private Service Connect 限制」一節中查看這些限制。

在本研究室中，您將建立簡單的架構，說明如何使用 PSA 和 PSC 端點存取權搭配 CloudSQL。

圖 1.

在本研究室中，您需要兩個專案，或在同一個專案中建立不同的虛擬私有雲。

注意：您可以在 PSC 端點啟用全域存取權，讓其他區域的使用者存取端點。

目標

在本研究室中，您將瞭解如何執行下列工作：

• 啟用服務網路
• 設定 PSA
• 使用 PSA 建立 CloudSQL 執行個體
• 啟用 PSC 服務連結。
• 在消費者 VPC 中建立 PSC 端點，以連線至 CloudSQL 資料庫
• 在供應者和消費者虛擬私有雲中，驗證從測試 VM 存取 SQL 資料庫的權限

注意：這項設計可供多位使用者使用。請參閱Private Service Connect 多租戶相關說明。

2. 設定和需求

自助式環境設定

1. 登入 Google Cloud 控制台，然後建立新專案或重複使用現有專案。如果您還沒有 Gmail 或 Google Workspace 帳戶，請務必建立帳戶。

• 「Project name」是這個專案參與者的顯示名稱。這是 Google API 不會使用的字元字串。您隨時可以更新。
• 專案 ID 在所有 Google Cloud 專案中都是不重複的值，且無法變更 (設定後即無法變更)。Cloud 控制台會自動產生專屬字串，您通常不需要特別留意。在大多數程式碼研究室中，您都需要參照專案 ID (通常會以 PROJECT_ID 表示)。如果您不喜歡系統產生的 ID，可以隨機產生另一個 ID。或者，您也可以自行嘗試，看看是否可用。在這個步驟完成後就無法變更，且會在整個專案期間維持不變。
• 提醒您，有些 API 會使用第三個值，也就是「專案編號」。如要進一步瞭解這三個值，請參閱說明文件。

注意：專案 ID 在全球範圍內是唯一的，選取後就無法由其他人使用。你是該 ID 的唯一使用者。即使刪除專案，也無法再次使用該 ID

注意：如果你使用 Gmail 帳戶，可以將預設位置設為「無機構」。如果你使用 Google Workspace 帳戶，請選擇貴機構適用的位置。

2. 接下來，您需要在 Cloud 控制台中啟用帳單功能，才能使用 Cloud 資源/API。執行這個程式碼研究室不會產生太多費用，甚至可能完全不會產生費用。如要關閉資源，避免在本教學課程結束後繼續產生費用，您可以刪除建立的資源或專案。Google Cloud 新使用者可享有價值 $300 美元的免費試用期。

啟動 Cloud Shell

雖然 Google Cloud 可透過筆記型電腦遠端操作，但在本程式碼研究室中，您將使用 Google Cloud Shell，這是在雲端運作的指令列環境。

在 Google Cloud 控制台中，按一下右上方工具列的 Cloud Shell 圖示：

佈建並連線至環境的作業需要一些時間才能完成。完成後，畫面應如下所示：

這個虛擬機器會載入您需要的所有開發工具。提供永久的 5 GB 主目錄，而且在 Google Cloud 中運作，可大幅提升網路效能和驗證功能。您可以在瀏覽器中完成本程式碼研究室的所有工作。您不需要安裝任何東西。

3. 工作 1：使用 (Terraform) 設定資料庫專案的環境

請注意，啟用部分資源會產生費用。為降低成本，請務必在實驗室完成後刪除資源。建議你查看帳單，確認這項運動是否符合你的需求。

在資料庫專案中，我們將啟用服務網路、建立 VPC、建立 PSA 範圍、建立服務網路對等連線，以及建立防火牆規則。開啟 Cloud 控制台，然後選取要用於資料庫的專案。

1. 開啟控制台右上方的 Cloud Shell，確認 Cloud Shell 中顯示資料庫專案 ID 資料庫專案，確認任何允許存取權的提示。
2. 建立名為 terraform-db-psc 的資料夾，並移動到資料夾

mkdir terraform-db-psc  && cd terraform-db-psc

3. 建立 main.tf、variable.tf、nat-vm.tf 和 database.tf 檔案。

touch main.tf variable.tf nat-vm.tf database.tf 

4. 切換至 Cloud Shell 編輯器檢視畫面。選取「編輯器」，確認您已允許所有必要提示，以便介面載入。
5. 載入完成後，請依序前往「File」>「Open Folder」，然後前往 /home/your-user-name/terraform-db-psc，接著選取「Ok」，即可在編輯器中開啟資料夾。
6. 選取 variable.tf 檔案，然後新增以下內容。將 your-database-project-id-here 文字替換為實際的資料庫專案 ID，並加上引號。將 your-consumer-project-id-here 文字替換為實際的消費者專案 ID，並加上引號。

variable "project_id" {
  type = string
  default = "your-database-project-id-here"
}

variable "project_id_consumer" {
  type = set(string)
  default = ["your-consumer-project-id-here"]
}

variable "network_id" {
  type = string
  default = "database-net"
}

variable "region_id" {
  type = string
  default = "us-east1"
}

variable "db_password" {
  type = string
  default = "cloudsql24"
}

7. 接下來，請開啟 main.tf 檔案。我們將新增一些 Terraform 程式碼，執行下文說明的各種動作。

啟用 API	resource "google_project_service" "default"
建立虛擬私有雲	resource "google_compute_network" "default"
新增防火牆規則	resource "google_compute_firewall" "allow_icmp"
建立 PSA 範圍	resource "google_compute_global_address" "psa_range"
建立對接	resource "google_service_networking_connection" "private_connection"

8. 複製並貼到 main .tf 檔案中。

resource "google_project_service" "default" {
 for_each = toset([
   "compute.googleapis.com",
   "servicenetworking.googleapis.com", 
   "sqladmin.googleapis.com",
   "cloudresourcemanager.googleapis.com"
 ])

 service            = each.value
 disable_on_destroy = false
}

resource "google_compute_network" "default" {
 project                = var.project_id
 name                    = var.network_id
 auto_create_subnetworks = true
 mtu                     = 1460
 routing_mode            = "GLOBAL"
}

resource "google_compute_global_address" "psa_range" {
  name                  = "psa-range-${google_compute_network.default.name}"
  project               = var.project_id
  purpose               = "VPC_PEERING"
  address_type          = "INTERNAL"
  prefix_length         = 20
  address               = "172.18.0.0"
  network               = google_compute_network.default.id

}

resource "google_service_networking_connection" "private_connection" {
  network = google_compute_network.default.self_link
  service = "servicenetworking.googleapis.com"

  reserved_peering_ranges = [
    google_compute_global_address.psa_range.name,
  ]
}

resource "google_compute_firewall" "allow_icmp" {
 name    = "allow-icmp-${google_compute_network.default.name}"
 network = google_compute_network.default.id
 project = var.project_id

 allow {
   protocol = "icmp"
 }

 source_ranges = ["0.0.0.0/0"]
 target_tags   = ["allow-icmp"]
}

resource "google_compute_firewall" "allow_ssh" {
 name    = "allow-ssh-${google_compute_network.default.name}"
 network = google_compute_network.default.id
 project = var.project_id

 allow {
   protocol = "tcp"
   ports    = ["22"]
 }

 source_ranges = ["0.0.0.0/0"]
 target_tags   = ["allow-ssh"]
}

resource "google_compute_firewall" "allow_sql" {
 name    = "allow-sql-${google_compute_network.default.name}"
 network = google_compute_network.default.id
 project = var.project_id

 allow {
   protocol = "tcp"
   ports    = ["3306"]
 }

 source_ranges = ["0.0.0.0/0"]
}

resource "google_compute_firewall" "allow_internal" {
 name    = "allow-internal-${google_compute_network.default.name}"
 network = google_compute_network.default.id
 project = var.project_id

 allow {
   protocol = "icmp"
 }

 allow {
   protocol = "tcp"
   ports    = ["0-65535"]
 }
 allow {
   protocol = "udp"
   ports    = ["0-65535"]
 }

 source_ranges = ["10.128.0.0/9", "172.18.0.0/20"] # Include PSA range
}

9. 切換回 Cloud Shell 終端機，確認您位於 terraform-db-psc 目錄 cd terraform-db-psc 中，然後執行下列指令

terraform init

初始化工作目錄。這個步驟會下載指定設定所需的供應器。

terraform plan

產生執行計畫，顯示 Terraform 將採取哪些動作來部署基礎架構。

10. 接著，請執行 terraform apply 指令來建立資源，然後輸入 yes 即可執行。

確認設定：

檢查環境是否已分配已啟用 Service-networking 的 VPC 網路對等互連 PSA IP 範圍

已建立名為 database-net 的自動模式虛擬私有雲

已建立防火牆規則

4. 工作 2：使用 PSA (Terraform) 建立 CloudSQL 執行個體

我們將使用 Terraform 建立 CloudSQL 執行個體，並使用 PSA 選項允許連線。在資料庫專案中完成這項設定。

1. 切換至 Cloud Shell 編輯器檢視畫面。確認您位於 terraform-db-psc 資料夾。選取 database.tf 檔案，然後新增以下內容。

resource "google_sql_database_instance" "default" {
  name             = "psc-psa-sql-db"
  region           = var.region_id
  database_version = "MYSQL_8_0"  
  settings {
    tier              = "db-f1-micro"
    availability_type = "REGIONAL"
    backup_configuration {
      enabled            = true
      binary_log_enabled = true
    }
    ip_configuration {      
      ipv4_enabled    = "false"
      private_network = google_compute_network.default.id
      
    }
  }
  deletion_protection = false 
}

resource "google_sql_user" "users" {
  name     = "testsql"
  instance = google_sql_database_instance.default.name
  password = var.db_password 
}

2. 切換回 Cloud Shell 終端機，確認您位於 terraform-db-psc 目錄中。接著，請執行 terraform apply 指令來建立資源，然後輸入 yes 即可執行。使用 PSA 建立 CloudSQL 執行個體可能需要 15 分鐘以上。

驗證資料庫

3. 完成後，請前往控制台的 SQL，選取新建立的 psc-psa-sql-db 資料庫執行個體。
4. 在左側展開 SQL 選項滑出式選單，然後選取「Connections」
5. 您可以在摘要分頁下方查看連線相關資訊。
6. 複製「內部 IP 位址」，並儲存在系統中的某處。如您所見，系統是從我們保留的範圍中指派這個 ID。
7. 你需要這個 IP 才能完成工作 3 步驟 5。

8. 在左側展開 SQL 選項滑出式選單，然後選取「使用者」。
9. 您應該會看到名為 testsql 的使用者，密碼為 cloudsql24(這會用於稍後存取資料庫)

確認設定：

1 個使用私人 IP 的 SQL 資料庫執行個體

1 個使用者，名稱為 testsql，密碼為 cloudsql24

5. 工作 3：建立測試 VM，並從資料庫專案 (Terraform) 連線至 SQL 執行個體

我們來使用 Terraform 建立測試 VM 和 NAT 閘道。在資料庫專案中完成這項設定。

1. 切換至 Cloud Shell 編輯器檢視畫面。確認您位於 terraform-db-psc 資料夾。選取 nat-vm.tf 檔案，然後新增以下內容。

resource "google_compute_router" "default" {
  name    = "outbound-nat"
  region  = var.region_id
  network = google_compute_network.default.id

 bgp {
  asn = 64514
  }
}

resource "google_compute_router_nat" "default" {
  name = "outbound-nat-gw"
  router = google_compute_router.default.name
  region = google_compute_router.default.region
  nat_ip_allocate_option = "AUTO_ONLY"
  source_subnetwork_ip_ranges_to_nat = "ALL_SUBNETWORKS_ALL_IP_RANGES"

  log_config {
    enable = true
    filter = "ERRORS_ONLY"
  }
}


resource "google_compute_instance" "sql_net_vm" {
  name         = "db-vm-test"
  machine_type = "e2-medium"
  zone         = "${var.region_id}-b"
  project      = var.project_id

  boot_disk {
    initialize_params {
      image = "debian-cloud/debian-11"
    }
  }

  network_interface {
    network = google_compute_network.default.self_link
  }

  # No external IP address
  network_performance_config {
    total_egress_bandwidth_tier = "DEFAULT"
  }

  tags = ["allow-icmp", "allow-ssh", "allow-internal", "allow-health-check"]

  # Install MariaDB at startup
  metadata_startup_script = <<EOF
#!/bin/bash
apt-get update
apt-get install -y mariadb-server
systemctl enable mariadb
EOF
}

2. 切換回 Cloud Shell 終端機，確認您位於 terraform-db-psc 目錄中。接著，請執行 terraform plan, then terraform apply 指令來建立資源，然後輸入 yes 即可執行。這會建立 NAT 閘道和已安裝 MariaDB 的 VM。

驗證資料庫

在消費者專案中完成這項操作

3. 前往「VM Instance」。選取 db-vm-test
4. 選取「SSH」SSH選項，連線至 VM。
5. 透過先前複製的本機 IP 連線至資料庫，方法如下：

mysql --host=172.18.0.2 --user=testsql --password=cloudsql24

附註：請將 IP 位址變更為實際 IP 位址，才能連線。

6. 連線建立後，請使用下列 localvpcsqldb 建立資料庫。

CREATE DATABASE localvpcsqldb;

7. 完成後，輸入 exit 即可退出連線。再次輸入 exit 即可關閉 VM。

確認設定：

1 個網路位址轉譯 (NAT) 閘道

1 個名為 db-vm-test 的 VM

6. 工作 4：在 CloudSQL 執行個體上啟用 PSC

接著，我們將使用 gcloud 指令啟用 PSC 選項，允許連線。在資料庫專案中完成這項設定。

1. 切換至「Cloud Shell」檢視畫面。
2. 在 Cloud Shell 中執行下列指令。

• 請將 Ensure YOUR_DB_PROJECT_HERE 替換為資料庫專案 ID。
• 請將 Ensure YOUR_CONSUMER_PROJECT_HERE 替換為消費者專案 ID。

project_id=YOUR_DB_PROJECT_HERE
allowed_project=YOUR_CONSUMER_PROJECT_HERE

gcloud beta sql instances patch psc-psa-sql-db \
--project=$project_id \
--enable-private-service-connect \
--allowed-psc-projects=$allowed_project

3. 這會更新現有資料庫，並附上 PSC 檔案。這項作業需要 10 分鐘以上。

如果您收到等待逾時錯誤，系統也會提供指令，讓您繼續查看進度。例如："您可以執行 `gcloud beta sql operations wait –project " 繼續等待作業。

請注意，您可以從一開始部署已啟用 PSA 和 PSC 的資料庫 。

驗證資料庫

4. 完成後，請前往控制台的「SQL」，選取「psc-psa-sql-db」資料庫執行個體。
5. 在左側展開 SQL 選項滑出式選單，然後選取「Connections」
6. 您可以在摘要分頁下方查看連線相關資訊。
7. 複製服務附件的網址，並儲存在系統中的某處。
8. 您需要這項資訊才能完成下一個任務 5 步驟 8。

確認設定：

1 個 SQL 資料庫執行個體，含服務附件

7. 工作 5：設定消費者專案的環境 (Terraform)

在消費者專案中，我們會建立內含防火牆規則和子網路的自訂虛擬私有雲。開啟 Cloud 控制台，然後選取要使用的專案。

1. 在控制台頂端的 Google Cloud 圖示右側，點選下拉式選單，然後選取「全部」分頁。

2. 從清單中的專案中選取消費者專案 ID 即可繼續操作。
3. 開啟控制台右上方的 Cloud Shell，確認 Cloud Shell 中顯示消費者專案 ID，確認任何允許存取權的提示。
4. 建立名為 terraform-consumer-psc 的資料夾並移動到資料夾

mkdir terraform-consumer-psc  && cd terraform-consumer-psc

5. 建立 main.tf、variable.tf 和 psc.tf 檔案。

touch main.tf variable.tf psc.tf 

6. 切換至 消費者專案 ID 的 Cloud Shell 編輯器檢視畫面。選取「編輯器」，確認您已允許所有必要提示，以便介面載入。
7. 載入完成後，請依序點選「File」>「Open Folder」，然後前往 /home/your-user-name/terraform-consumer-psc，接著選取「Ok」，即可在編輯器中開啟資料夾。
8. 選取 variable.tf 檔案，然後新增以下內容。將 your-consumer-project-id-here 文字替換為實際的消費者專案 ID，並加上引號。將 your-psc-attachment-id-here 文字替換為 psc 附件地址，並加上引號。這是您在工作 4 的 5 至 7 節複製的 ID

variable "project_id" {
  type = string
  default = "your-consumer-project-id-here"
}

variable "psc_attachment_id" {
  type = string
  default = "your-psc-attachment-id-here"
}

variable "network_id" {
  type = string
  default = "psc-endpoint-vpc"
}

variable "region_id" {
  type = string
  default = "us-east1"
}

9. 接下來，請開啟 main.tf 檔案。我們將新增一些 Terraform 程式碼，執行下文說明的各種動作。

啟用 API	resource "google_project_service"
建立虛擬私有雲	resource "google_compute_network"
建立 NAT 閘道	resource "google_compute_router" resource "google_compute_router_nat"
新增防火牆規則	resource "google_compute_firewall"

10. 複製並貼到 main .tf 檔案中。

resource "google_project_service" "default" {
  for_each = toset([
    "compute.googleapis.com",
    "cloudresourcemanager.googleapis.com"
  ])

  service            = each.value
  disable_on_destroy = false
}

resource "google_compute_network" "default" {
  project                 = var.project_id
  name                    = var.network_id
  auto_create_subnetworks = false
  mtu                     = 1460
  routing_mode            = "GLOBAL"
}

resource "google_compute_subnetwork" "vm_subnet_pc" {
  name          = "vm-net"
  ip_cidr_range = "192.168.80.0/24"
  region        = var.region_id
  network       = google_compute_network.default.name
  project       = var.project_id
}

resource "google_compute_subnetwork" "psc_subnet_ip" {
  name          = "psc-subnet"
  ip_cidr_range = "192.168.100.0/24"
  region        = var.region_id
  network       = google_compute_network.default.name
  project       = var.project_id
}

resource "google_compute_router" "default" {
  name    = "outbound-nat"
  region  = var.region_id
  network = google_compute_network.default.id

 bgp {
  asn = 64514
  }
}

resource "google_compute_router_nat" "default" {
  name = "outbound-nat-gw"
  router = google_compute_router.default.name
  region = google_compute_router.default.region
  nat_ip_allocate_option = "AUTO_ONLY"
  source_subnetwork_ip_ranges_to_nat = "ALL_SUBNETWORKS_ALL_IP_RANGES"

  log_config {
    enable = true
    filter = "ERRORS_ONLY"
  }
}

resource "google_compute_firewall" "allow_icmp" {
  name    = "allow-icmp-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
  }

  source_ranges = ["0.0.0.0/0"]
  
}

resource "google_compute_firewall" "allow_ssh" {
  name    = "allow-ssh-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["allow-ssh"]
}


resource "google_compute_firewall" "allow_internal" {
  name    = "allow-internal-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
    }


  allow {
    protocol = "tcp"
    ports    = ["0-65535"]
  }
  allow {
    protocol = "udp"
    ports    = ["0-65535"]
  }

  source_ranges = ["192.168.0.0/16"]
 }

11. 切換回 Cloud Shell 終端機，確認您位於消費端專案中的 terraform-consumer-psc 目錄 cd terraform-consumer-psc，然後執行下列指令

terraform init

初始化工作目錄。這個步驟會下載指定設定所需的供應器。

terraform plan

產生執行計畫，顯示 Terraform 將採取哪些動作來部署基礎架構。

12. 接著，請執行 terraform apply 指令來建立資源，然後輸入 yes 即可執行。

確認設定：

請檢查環境是否有以下情況：

1 個名為 psc-endpoint-vpc 的自訂 VPC

防火牆規則 NAT 閘道

8. 工作 6：在消費者專案和測試 VM 中，建立 PSC 端點至 SQL DB 附件 (Terraform)

在消費者專案中完成這項設定。

1. 切換回 Cloud Shell 編輯器，開啟 terraform-consumer-psc 目錄，然後選取 psc.tf 檔案。在檔案中新增下列 Terraform 程式碼。這會建立靜態內部 IP、PSC 端點，以及已安裝 Maria DB 的測試 VM。

resource "google_compute_address" "default" {
  name = "psc-ip-1"
  region = var.region_id
  address_type = "INTERNAL"
  subnetwork = google_compute_subnetwork.psc_subnet_ip.name
  address = "192.168.100.100" 
}

resource "google_compute_forwarding_rule" "default" {
  name = "psc-sql-endpoint"
  region = var.region_id
  network = google_compute_network.default.name
  ip_address = google_compute_address.default.self_link
  load_balancing_scheme = ""
  target = var.psc_attachment_id
}


resource "google_compute_instance" "sql_test_vm" {
  name         = "remote-sql-test-vm"
  machine_type = "e2-medium"
  zone         = "${var.region_id}-b"
  project      = var.project_id

  boot_disk {
    initialize_params {
      image = "debian-cloud/debian-11"
    }
  }

  network_interface {
    subnetwork = google_compute_subnetwork.vm_subnet_pc.name
  }

  # No external IP address
  network_performance_config {
    total_egress_bandwidth_tier = "DEFAULT"
  }

  tags = ["allow-icmp", "allow-ssh", "allow-internal", "allow-health-check"]

  # Install MariaDB at startup
  metadata_startup_script = <<EOF
#!/bin/bash
apt-get update
apt-get install -y mariadb-server
systemctl enable mariadb
EOF
}

2. 切換回 Cloud Shell 終端機，確認您位於消費端專案中的 terraform-consumer-psc 目錄 cd terraform-consumer-psc，然後執行下列指令

terraform plan

產生執行計畫，顯示 Terraform 將採取哪些動作來部署基礎架構。

3. 接著，請執行 terraform apply 指令來建立資源，然後輸入 yes 即可執行

9. 工作 7：透過 PSC IP 位址驗證 VM 的端點連線

在消費者專案中完成這項操作

8. 前往「VM Instance」。選取「remote-sql-test-vm」remote-sql-test-vm
9. 選取「SSH」SSH選項，連線至 VM。
10. 透過下列項目，透過端點連線至資料庫：

mysql --host=192.168.100.100 --user=testsql --password=cloudsql24

11. 連線建立完成後，請使用以下 psc-sql-db 建立資料庫。

CREATE DATABASE remotepscpsasqldb;

12. 完成後，輸入 exit 即可退出連線。再次輸入 exit 即可關閉 VM。

10. 工作 8：驗證資料庫項目

在資料庫專案中完成這項驗證

1. 在控制台頂端的 Google Cloud 圖示右側，點選下拉式選單，然後選取「全部」分頁。

2. 從列出的專案中選取「資料庫」專案 ID 即可繼續操作。
3. 前往「SQL」，選取資料庫「psc-psa-sql-db」，展開 SQL 選項並選取「資料庫」。您應該會在消費者專案 VM 中看到剛建立的資料庫 (稱為 remotepscpsasqldb)，以及在資料庫專案 VM 中看到 localvpcsqldb**.**

注意：您也可以使用 DNS 名稱連線。如要進一步瞭解如何設定 DNS，請參閱「設定 DNS 代管區域和 DNS 記錄」一文。

11. 清除

請務必清除所用資源，以免產生不必要的費用。

在消費者專案中完成這項操作

1. 選取消費者專案 ID
2. 前往 Cloud Shell，確認您看到消費端專案 ID
3. 前往 terraform-consumer-psc 目錄 cd terraform-consumer-psc 並執行下列指令 terraform destroy，然後輸入 yes，您在消費者專案中使用 Terraform 建立的所有資源都會移除。

在資料庫專案中完成這項操作

1. 選取資料庫專案 ID
2. 前往 Cloud Shell，確認您看到資料庫專案 ID
3. 前往 terraform-db-psc 目錄 cd terraform-db-psc 並執行下列指令 terraform destroy，然後輸入 yes，您在資料庫專案中使用 Terraform 建立的大部分資源都會移除。可能無法刪除服務網路，並顯示錯誤。
4. 接著，請從 terraform-db-psc 資料夾中刪除下列檔案。

rm -r terraform.tfstate terraform.tfstate.backup

5. 接著在控制台中前往「VPC 網路」
6. 選取 database-net VPC，選取「PRIVATE SERVICES ACCESS」，在「Allocated IP Ranges for Services」下方，選取 psa-range-database-net，然後選取「Release」選項

7. 接著選取「VPC NETWORK PEERING」，選取「servicenetworking-googleapis-com」，然後選取「Delete」選項。

8. 接著選取「Delete VPC network」

12. 恭喜

恭喜！您已成功設定含有 PSA 和 PSC 連結的 Cloud SQL 執行個體，並在其他 VPC 中建立 Private Service Connect 端點。

瞭解詳情

如要進一步瞭解 Private Service Connect 和 Cloud SQL，

其他相關程式碼研究室：https://codelabs.developers.google.com/codelabs/cloudsql-psc-terraform