1. 개요
다른 프로젝트 또는 VPC에서 비공개 Cloud SQL 인스턴스에 연결하는 방법에는 여러 가지가 있습니다. Private Service Connect (PSC)를 사용하면 서비스 제작자가 서비스 연결을 통해 서비스를 노출할 수 있습니다. 이러한 서비스 연결은 소비자가 환경에서 PSC 엔드포인트 또는 PSC 백엔드를 만들고 지정된 비공개 IP를 통해 이러한 프로듀서 서비스에 연결하는 데 사용할 수 있습니다.
Cloud SQL은 PSC 서비스 연결을 활용하여 비공개 연결을 허용할 수 있습니다. 이 실습에서는 이 옵션을 구성하고 테스트할 수 있습니다.
이 실습에서는 CloudSQL에서 PSC 엔드포인트 액세스를 사용하는 방법을 보여주는 간단한 아키텍처를 빌드합니다.
그림 1.
이 실습에서는 프로젝트 2개 또는 동일한 프로젝트의 별도 VPC가 필요합니다.
목표
이 실습에서는 다음 작업을 실행하는 방법을 알아봅니다.
- PSC 서비스 연결을 사용하여 CloudSQL 인스턴스를 만듭니다.
- 고정 IP 주소 만들기
- CloudSQL 데이터베이스에 연결할 PSC 엔드포인트를 소비자 VPC에 만듭니다.
- PSC 엔드포인트 IP를 통해 소비자 네트워크의 테스트 VM에서 SQL 데이터베이스에 액세스할 수 있는지 확인합니다.
2. 설정 및 요구사항
자습형 환경 설정
- Google Cloud Console에 로그인하여 새 프로젝트를 만들거나 기존 프로젝트를 재사용합니다. 아직 Gmail이나 Google Workspace 계정이 없는 경우 계정을 만들어야 합니다.
- 프로젝트 이름은 이 프로젝트 참가자의 표시 이름입니다. 이는 Google API에서 사용하지 않는 문자열이며 언제든지 업데이트할 수 있습니다.
- 프로젝트 ID는 모든 Google Cloud 프로젝트에서 고유하며, 변경할 수 없습니다(설정된 후에는 변경할 수 없음). Cloud 콘솔은 고유한 문자열을 자동으로 생성합니다. 일반적으로는 신경 쓰지 않아도 됩니다. 대부분의 Codelab에서는 프로젝트 ID (일반적으로
PROJECT_ID로 식별됨)를 참조해야 합니다. 생성된 ID가 마음에 들지 않으면 다른 임의 ID를 생성할 수 있습니다. 또는 직접 시도해 보고 사용 가능한지 확인할 수도 있습니다. 이 단계 이후에는 변경할 수 없으며 프로젝트 기간 동안 유지됩니다. - 참고로 세 번째 값은 일부 API에서 사용하는 프로젝트 번호입니다. 이 세 가지 값에 대한 자세한 내용은 문서를 참고하세요.
- 다음으로 Cloud 리소스/API를 사용하려면 Cloud 콘솔에서 결제를 사용 설정해야 합니다. 이 Codelab 실행에는 많은 비용이 들지 않습니다. 이 튜토리얼이 끝난 후에 요금이 청구되지 않도록 리소스를 종료하려면 만든 리소스 또는 프로젝트를 삭제하면 됩니다. Google Cloud 신규 사용자는 300달러(USD) 상당의 무료 체험판 프로그램에 참여할 수 있습니다.
Cloud Shell 시작
Google Cloud를 노트북에서 원격으로 실행할 수 있지만, 이 Codelab에서는 Cloud에서 실행되는 명령줄 환경인 Google Cloud Shell을 사용합니다.
Google Cloud Console의 오른쪽 상단 툴바에 있는 Cloud Shell 아이콘을 클릭합니다.
환경을 프로비저닝하고 연결하는 데 몇 분 정도 소요됩니다. 완료되면 다음과 같이 표시됩니다.
가상 머신에는 필요한 개발 도구가 모두 들어있습니다. 영구적인 5GB 홈 디렉터리를 제공하고 Google Cloud에서 실행되므로 네트워크 성능과 인증이 크게 개선됩니다. 이 Codelab의 모든 작업은 브라우저 내에서 수행할 수 있습니다. 아무것도 설치할 필요가 없습니다.
3. 작업 1. (Terraform)을 사용하여 데이터베이스 프로젝트의 환경 설정
데이터베이스 프로젝트에서 방화벽 규칙과 서브넷이 있는 커스텀 VPC를 만듭니다. Cloud 콘솔을 열고 데이터베이스에 사용할 프로젝트를 선택합니다.
- 콘솔 오른쪽 상단에 있는 Cloud Shell을 열고 Cloud Shell에 데이터베이스 프로젝트의 데이터베이스 프로젝트 ID가 표시되는지 확인한 다음 액세스를 허용하라는 메시지가 표시되면 확인합니다.
- terraform-db라는 폴더를 만들고 해당 폴더로 이동합니다.
mkdir terraform-db && cd terraform-db
- main.tf, variable.tf, database.tf 파일을 만듭니다.
touch main.tf variable.tf database.tf
- Cloud Shell 편집기 뷰로 전환합니다. 편집기를 선택하고 인터페이스를 로드할 수 있도록 필요한 프롬프트를 허용합니다.
- 로드되면 파일 > 폴더 열기로 이동하여 /home/your-user-name/terraform-db로 이동하고 확인을 선택하여 편집기에서 폴더를 엽니다.
- variable.tf 파일을 선택하고 다음을 추가합니다.
your-database-project-id-here텍스트를 실제 데이터베이스 프로젝트 ID(따옴표 포함)로 바꿉니다.your-consumer-project-id-here텍스트를 실제 소비자 프로젝트 ID(따옴표 포함)로 바꿉니다.
variable "project_id" {
type = string
default = "your-database-project-id-here"
}
variable "project_id_consumer" {
type = set(string)
default = ["your-consumer-project-id-here"]
}
variable "network_id" {
type = string
default = "database-net"
}
variable "region_id" {
type = string
default = "us-east1"
}
variable "db_password" {
type = string
default = "cloudsql24"
}
- 그런 다음 main.tf 파일을 엽니다. 아래에 설명된 대로 다양한 작업을 실행하는 terraform 코드를 추가합니다.
API 사용 설정 |
|
VPC 만들기 |
|
방화벽 규칙 추가 |
|
- 다음을 복사하여 main .tf 파일에 붙여넣습니다.
resource "google_project_service" "default" {
for_each = toset([
"compute.googleapis.com",
"sqladmin.googleapis.com"
])
service = each.value
disable_on_destroy = false
}
resource "google_compute_network" "default" {
project = var.project_id
name = var.network_id
auto_create_subnetworks = true
mtu = 1460
routing_mode = "GLOBAL"
}
resource "google_compute_firewall" "allow_icmp" {
name = "allow-icmp-${google_compute_network.default.name}"
network = google_compute_network.default.id
project = var.project_id
allow {
protocol = "icmp"
}
source_ranges = ["0.0.0.0/0"]
target_tags = ["allow-icmp"]
}
resource "google_compute_firewall" "allow_ssh" {
name = "allow-ssh-${google_compute_network.default.name}"
network = google_compute_network.default.id
project = var.project_id
allow {
protocol = "tcp"
ports = ["22"]
}
source_ranges = ["0.0.0.0/0"]
target_tags = ["allow-ssh"]
}
resource "google_compute_firewall" "allow_sql" {
name = "allow-sql-${google_compute_network.default.name}"
network = google_compute_network.default.id
project = var.project_id
allow {
protocol = "tcp"
ports = ["3306"]
}
source_ranges = ["0.0.0.0/0"]
}
resource "google_compute_firewall" "allow_internal" {
name = "allow-internal-${google_compute_network.default.name}"
network = google_compute_network.default.id
project = var.project_id
allow {
protocol = "icmp"
}
allow {
protocol = "tcp"
ports = ["0-65535"]
}
allow {
protocol = "udp"
ports = ["0-65535"]
}
source_ranges = ["10.128.0.0/9"]
}
- Cloud Shell 터미널로 다시 전환하여 terraform-db 디렉터리
cd terraform-db에 있는지 확인하고 다음 명령어를 실행합니다.
terraform init
작업 디렉터리를 초기화합니다. 이 단계에서는 지정된 구성에 필요한 제공자를 다운로드합니다.
terraform plan
Terraform이 인프라를 배포하기 위해 취할 작업을 보여주는 실행 계획을 생성합니다.
- 이제 리소스를 만들려면
terraform apply명령어를 실행하고yes를 입력하여 실행합니다.
4. 작업 2. PSC 첨부로 CloudSQL 인스턴스 만들기 (Terraform)
Terraform을 사용하여 연결을 허용하는 PSC 옵션이 있는 CloudSQL 인스턴스를 만들어 보겠습니다. 데이터베이스 프로젝트에서 이 구성을 완료합니다.
- Cloud Shell 편집기 뷰로 전환합니다. 현재 위치가
terraform-db폴더인지 확인합니다.database.tf파일을 선택하고 다음을 추가합니다.
resource "google_sql_database_instance" "default" {
name = "psc-sql-db"
region = var.region_id
database_version = "MYSQL_8_0"
settings {
tier = "db-f1-micro"
availability_type = "REGIONAL"
backup_configuration {
enabled = true
binary_log_enabled = true
}
ip_configuration {
psc_config {
psc_enabled = true
allowed_consumer_projects = var.project_id_consumer
}
ipv4_enabled = false
}
}
deletion_protection = false
}
resource "google_sql_user" "users" {
name = "testsql"
instance = google_sql_database_instance.default.name
password = var.db_password
}
- Cloud Shell 터미널로 다시 전환하고 terraform-db 디렉터리에 있는지 확인합니다. 이제 리소스를 만들려면
terraform apply명령어를 실행하고yes를 입력하여 실행합니다. PSC를 연결하여 CloudSQL 인스턴스를 만드는 데 최대 5분이 걸릴 수 있습니다.
데이터베이스 확인
- 완료되면 콘솔에서 SQL로 이동하여 새로 만든 psc-sql-db 데이터베이스 인스턴스를 선택합니다.
- 왼쪽에서 SQL 옵션 슬라이드아웃을 펼치고 연결을 선택합니다.
- 요약 탭에서 연결에 관한 정보를 확인할 수 있습니다.
- 서비스 첨부파일 주소를 복사하여 시스템의 다른 곳에 저장합니다.
- 작업 3 단계 8을 완료하려면 이 정보가 필요합니다.
- 왼쪽에서 SQL 옵션 슬라이드아웃을 펼치고 사용자를 선택합니다.
- 비밀번호가 cloudsql24인 testsql이라는 사용자 이름이 표시됩니다. 이 사용자 이름은 나중에 DB에 액세스하는 데 사용됩니다.
5. 작업 3. 소비자 프로젝트의 환경 설정 (Terraform)
소비자 프로젝트에서 방화벽 규칙과 서브넷이 있는 커스텀 VPC를 만듭니다. Cloud 콘솔을 열고 사용할 프로젝트를 선택합니다.
- 콘솔 상단의 오른쪽에 있는 Google Cloud 아이콘 옆에 있는 드롭다운을 클릭한 다음 all 탭을 선택합니다.
- 나열된 프로젝트에서 소비자 프로젝트 ID를 선택하여 계속 진행합니다.
- 콘솔 오른쪽 상단에 있는 Cloud Shell을 열고 Cloud Shell에 소비자 프로젝트 ID가 표시되는지 확인한 후 액세스를 허용하라는 메시지가 표시되면 확인합니다.
- terraform-consumer라는 폴더를 만들고 해당 폴더로 이동합니다.
mkdir terraform-consumer && cd terraform-consumer
- main.tf, variable.tf, psc.tf 파일을 만듭니다.
touch main.tf variable.tf psc.tf
- 소비자 프로젝트 ID의 Cloud Shell 편집기 뷰로 전환합니다. 편집기를 선택하고 인터페이스를 로드할 수 있도록 필요한 프롬프트를 허용합니다.
- 로드되면 파일 > 폴더 열기로 이동하여 /home/your-user-name/terraform-consumer로 이동하고 확인을 선택하여 편집기에서 폴더를 엽니다.
- variable.tf 파일을 선택하고 다음을 추가합니다.
your-consumer-project-id-here텍스트를 실제 소비자 프로젝트 ID로 바꾸고 따옴표로 묶습니다.your-psc-attachment-id-here텍스트를 psc 첨부파일 주소로 바꾸고 따옴표로 묶습니다. 2단계 2-5에서 복사한 ID입니다.
variable "project_id" {
type = string
default = "your-consumer-project-id-here"
}
variable "psc_attachment_id" {
type = string
default = "your-psc-attachment-id-here"
}
variable "network_id" {
type = string
default = "psc-endpoint-net"
}
variable "region_id" {
type = string
default = "us-east1"
}
variable "region_id2" {
type = string
default = "us-central1"
}
- 그런 다음 main.tf 파일을 엽니다. 아래에 설명된 대로 다양한 작업을 실행하는 terraform 코드를 추가합니다.
API 사용 설정 |
|
VPC 만들기 |
|
NAT 게이트웨이 만들기 |
|
방화벽 규칙 추가 |
|
- 다음을 복사하여 main .tf 파일에 붙여넣습니다.
resource "google_project_service" "default" {
for_each = toset([
"compute.googleapis.com",
"cloudresourcemanager.googleapis.com"
])
service = each.value
disable_on_destroy = false
}
resource "google_compute_network" "default" {
project = var.project_id
name = var.network_id
auto_create_subnetworks = false
mtu = 1460
routing_mode = "GLOBAL"
}
resource "google_compute_subnetwork" "vm_subnet" {
name = "vm-subnet"
ip_cidr_range = "192.168.50.0/24"
region = var.region_id2
network = google_compute_network.default.name
project = var.project_id
}
resource "google_compute_subnetwork" "psc_subnet" {
name = "psc-subnet"
ip_cidr_range = "192.168.90.0/24"
region = var.region_id
network = google_compute_network.default.name
project = var.project_id
}
resource "google_compute_router" "default" {
name = "outbound-nat"
region = var.region_id2
network = google_compute_network.default.id
bgp {
asn = 64514
}
}
resource "google_compute_router_nat" "default" {
name = "outbound-nat-gw"
router = google_compute_router.default.name
region = google_compute_router.default.region
nat_ip_allocate_option = "AUTO_ONLY"
source_subnetwork_ip_ranges_to_nat = "ALL_SUBNETWORKS_ALL_IP_RANGES"
log_config {
enable = true
filter = "ERRORS_ONLY"
}
}
resource "google_compute_firewall" "allow_icmp" {
name = "allow-icmp-${google_compute_network.default.name}"
network = google_compute_network.default.id
project = var.project_id
allow {
protocol = "icmp"
}
source_ranges = ["0.0.0.0/0"]
}
resource "google_compute_firewall" "allow_ssh" {
name = "allow-ssh-${google_compute_network.default.name}"
network = google_compute_network.default.id
project = var.project_id
allow {
protocol = "tcp"
ports = ["22"]
}
source_ranges = ["0.0.0.0/0"]
target_tags = ["allow-ssh"]
}
resource "google_compute_firewall" "allow_internal" {
name = "allow-internal-${google_compute_network.default.name}"
network = google_compute_network.default.id
project = var.project_id
allow {
protocol = "icmp"
}
allow {
protocol = "tcp"
ports = ["0-65535"]
}
allow {
protocol = "udp"
ports = ["0-65535"]
}
source_ranges = ["192.168.0.0/16"]
}
- Cloud Shell 터미널로 다시 전환하여 소비자 프로젝트의 terraform-consumer 디렉터리
cd terraform-consumer에 있는지 확인하고 다음 명령어를 실행합니다.
terraform init
작업 디렉터리를 초기화합니다. 이 단계에서는 지정된 구성에 필요한 제공자를 다운로드합니다.
terraform plan
Terraform이 인프라를 배포하기 위해 취할 작업을 보여주는 실행 계획을 생성합니다.
- 이제 리소스를 만들려면
terraform apply명령어를 실행하고yes를 입력하여 실행합니다.
6. 작업 4. 소비자 프로젝트 및 테스트 VM에서 SQL DB 연결에 대한 PSC 엔드포인트 만들기 (Terraform)
소비자 프로젝트에서 이 구성을 완료합니다.
- Cloud Shell 편집기로 다시 전환하여 terraform-consumer 디렉터리를 열고
psc.tf파일을 선택합니다. 다음 Terraform 코드를 파일에 추가합니다. 이렇게 하면 고정 내부 IP, PSC 엔드포인트, Maria DB가 설치된 테스트 VM이 생성됩니다.
resource "google_compute_address" "default" {
name = "psc-ip"
region = var.region_id
address_type = "INTERNAL"
subnetwork = google_compute_subnetwork.psc_subnet.name
address = "192.168.90.100"
}
resource "google_compute_forwarding_rule" "default" {
name = "psc-sql-endpoint"
region = var.region_id
network = google_compute_network.default.name
ip_address = google_compute_address.default.self_link
load_balancing_scheme = ""
target = var.psc_attachment_id
}
resource "google_compute_instance" "sql_test_vm" {
name = "sql-test-vm"
machine_type = "e2-medium"
zone = "${var.region_id2}-b"
project = var.project_id
boot_disk {
initialize_params {
image = "debian-cloud/debian-11"
}
}
network_interface {
subnetwork = google_compute_subnetwork.vm_subnet.name
}
# No external IP address
network_performance_config {
total_egress_bandwidth_tier = "DEFAULT"
}
tags = ["allow-icmp", "allow-ssh", "allow-internal", "allow-health-check"]
# Install MariaDB at startup
metadata_startup_script = <<EOF
#!/bin/bash
apt-get update
apt-get install -y mariadb-server
systemctl enable mariadb
EOF
}
- Cloud Shell 터미널로 다시 전환하여 소비자 프로젝트의 terraform-consumer 디렉터리
cd terraform-consumer에 있는지 확인하고 다음 명령어를 실행합니다.
terraform plan
Terraform이 인프라를 배포하기 위해 취할 작업을 보여주는 실행 계획을 생성합니다.
- 이제 리소스를 만들려면
terraform apply명령어를 실행하고yes를 입력하여 실행합니다. - VM과 엔드포인트가 서로 다른 리전에 있으므로 PSC 엔드포인트에서 전역 액세스를 사용 설정해야 합니다. 콘솔을 통해 이 작업을 수행합니다.
- 소비자 프로젝트 콘솔에서 Private Service Connect로 이동합니다. 연결된 엔드포인트 탭의 엔드포인트 섹션에서 psc-sql-endpoint를 선택합니다.
- 이제 수정을 선택한 다음 전역 액세스 사용 설정 및 저장 옵션 옆의 체크박스를 클릭합니다.
- 다음 단계로 이동하여 연결을 확인합니다.
7. 작업 5. PSC IP 주소를 통해 VM에서 엔드포인트 연결 확인
소비자 프로젝트에서 완료
- VM 인스턴스로 이동합니다. sql-test-vm을 선택합니다.
- SSH 옵션을 선택하여 VM에 연결합니다.
- 다음을 사용하여 엔드포인트를 통해 DB에 연결합니다.
mysql --host=192.168.90.100 --user=testsql --password=cloudsql24
- 연결이 설정되면 다음 psc-sql-db를 사용하여 데이터베이스를 만듭니다.
CREATE DATABASE remotesqldb;
- 완료되면 exit를 입력하여 연결을 종료합니다.
8. 작업 6. 데이터베이스 항목 확인
데이터베이스 프로젝트에서 이 인증을 완료합니다.
- 콘솔 상단의 오른쪽에 있는 Google Cloud 아이콘 옆에 있는 드롭다운을 클릭한 다음 all 탭을 선택합니다.
- 나열된 프로젝트에서 데이터베이스 프로젝트 ID를 선택하여 계속합니다.
- SQL로 이동하여 데이터베이스 psc-sql-db를 선택하고 SQL 옵션을 펼치고 데이터베이스를 선택합니다. 소비자 프로젝트 VM에서 방금 만든 remotesqldb라는 데이터베이스가 표시됩니다.**
.**
9. 삭제
데이터베이스 프로젝트에서 완료
- 데이터베이스 프로젝트 ID 선택
- Cloud Shell로 이동하여 데이터베이스 프로젝트 ID가 표시되는지 확인합니다.
- terraform-db 디렉터리
cd terraform-db로 이동하여 다음 명령어terraform destroy를 실행하고yes를 입력하면 Terraform으로 db 프로젝트에서 만든 모든 리소스가 삭제됩니다.
소비자 프로젝트에서 완료
- 소비자 프로젝트 ID 선택
- Cloud Shell로 이동하여 소비자 프로젝트 ID가 표시되는지 확인합니다.
- terraform-consumer 디렉터리
cd terraform-consumer로 이동하여 다음 명령어terraform destroy를 실행하고yes를 입력하면 Terraform으로 db 프로젝트에서 만든 모든 리소스가 삭제됩니다.
10. 축하합니다
축하합니다. PSC 연결이 포함된 Cloud SQL 인스턴스를 구성하고 다른 VPC에 Private Service Connect 엔드포인트를 만들었습니다. PSC 엔드포인트를 통해 원격 VM에서 데이터베이스에 성공적으로 연결했습니다.
자세히 알아보기
Private Service Connect 및 Cloud SQL에 대해 자세히 알아보세요.