Эта страница переведена с помощью Cloud Translation API.

Публикация события в Cloud Pub/Sub с помощью ABAP SDK для Google Cloud

1. Введение

В этой лабораторной работе мы перечислили шаги по публикации события в API Google Cloud Pub/Sub с использованием ABAP SDK для Google Cloud .

В этой лабораторной работе используются следующие сервисы Google Cloud:

Паб/Саб
Cloud Shell

Что вы построите

Вы узнаете следующее:

Включить Pub/Sub в проекте Google Cloud.
Создайте тему Pub/Sub.
Публикуйте сообщения.

2. Прежде чем начать

Вы установили ABAP SDK для Google Cloud в своей системе. Чтобы настроить новую систему, обратитесь к практическому руководству по установке пробной версии ABAP на Google Cloud Platform .
Вы используете Cloud Shell — среду командной строки, работающую в Google Cloud. В консоли Cloud Console нажмите «Активировать Cloud Shell» в правом верхнем углу:

Выполните следующие команды для аутентификации вашей учётной записи и установите проект по умолчанию abap-sdk-poc . Зона us-west4-b используется в качестве примера. При необходимости измените проект и зону в следующих командах по своему усмотрению.

gcloud auth login
gcloud config set project abap-sdk-poc
gcloud config set compute/zone us-west4-b

3. Обзор

В объем данной лабораторной работы входят следующие компоненты службы Pub/Sub:

Издатель (также называемый производителем): создает сообщения и отправляет (публикует) их в службу обмена сообщениями по указанной теме.
Сообщение: данные, которые перемещаются через службу обмена сообщениями.
Тема: именованная сущность, представляющая собой поток сообщений.

4. Настройте службу Pub/Sub

Чтобы создать учетную запись службы с необходимой ролью, выполните следующую команду в терминале Cloud Shell:

gcloud iam service-accounts create abap-sdk-pubsub-tester --display-name="Service Account for PubSub"

Чтобы включить API Pub/Sub для вашей учетной записи службы ( abap-sdk-poc ), выполните следующую команду в терминале Cloud Shell:

gcloud services enable pubsub.googleapis.com

Предоставьте сервисной учётной записи IAM роль pubsub.topics.create , чтобы иметь возможность создавать темы. Выполните следующую команду в терминале Cloud Shell:

gcloud endpoints services add-iam-policy-binding pubsub.googleapis.com \ --member='serviceAccount:abap-sdk-pubusb-tester@abap-sdk-poc.iam.gserviceaccount.com' \
--role='roles/roles/pubsub.topics.create'

Предоставьте сервисной учётной записи IAM-роль pubsub.topics.publish , чтобы публиковать сообщения в теме. Выполните следующую команду в терминале Cloud Shell:

gcloud endpoints services add-iam-policy-binding pubsub.googleapis.com \ --member='serviceAccount:abap-sdk-pubusb-tester@abap-sdk-poc.iam.gserviceaccount.com' \
--role='roles/roles/pubsub.topics.publish'

Чтобы убедиться, что роли добавлены, перейдите на страницу IAM . Созданная вами учётная запись службы должна быть указана в списке вместе с назначенными ей ролями.

5. Настройте клиентский ключ

Чтобы сохранить конфигурацию в таблице /GOOG/CLIENT_KEY , выполните следующие действия:

В графическом интерфейсе SAP введите код транзакции SPRO .
Нажмите ссылку SAP IMG .
Нажмите ABAP SDK для Google Cloud > Основные настройки > Настроить ключ клиента .
Нажмите «Новые записи» .
Введите значения для следующих полей:

Поле	Описание
Имя ключа Google Cloud	PUBSUB_DEMO
Имя учетной записи облачной службы Google	abap-sdk-dev@abap-sdk-poc.iam.gserviceaccount.com
Область применения Google Cloud	https://www.googleapis.com/auth/cloud-platform
Идентификатор проекта Google Cloud	abap-sdk-poc
Класс авторизации	/GOOG/CL_AUTH_GOOGLE

Оставьте остальные поля пустыми.

6. Создайте тему

Тема создаётся с помощью метода CREATE_TOPICS заглушки API /GOOG/CL_PUBSUB_V1. Сигнатура метода:

В графическом интерфейсе SAP введите код транзакции SE38 .
Создайте отчет с именем ZPUBSUB_DEMO .
В открывшемся всплывающем окне введите данные, как показано ниже, и нажмите кнопку «Сохранить».

В следующем всплывающем окне выберите Локальный объект или укажите имя пакета, если необходимо.
В редакторе ABAP добавьте следующий код:

" Data Declaration
DATA:
  lo_client        TYPE REF TO /goog/cl_pubsub_v1.

TRY.
    " Open HTTP Connection
    CREATE OBJECT lo_client EXPORTING iv_key_name = 'PUBSUB_DEMO'.

    " Populate relevant parameters
    DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
    DATA(lv_p_topics_id) = CONV string( 'PUBSUB_DEMO_TOPIC' ).

    " Call API method pubsub.topics.create
    lo_client->create_topics(
      EXPORTING
        iv_p_projects_id = lv_p_projects_id
        iv_p_topics_id   = lv_p_topics_id
      IMPORTING
      es_output        = DATA(ls_output)
      ev_ret_code      = DATA(lv_ret_code)
      ev_err_text      = DATA(lv_err_text)
      es_err_resp      = DATA(ls_err_resp) ).

    IF lo_client->is_success( lv_ret_code ) = abap_true.
      DATA(lv_msg) = 'Topic ' && ':' && lv_p_topics_id && ' was created!'.
      MESSAGE lv_msg TYPE 'I' .
    ELSE.
      MESSAGE lv_err_text TYPE 'E'.
    ENDIF.

    " Close HTTP Connection
    lo_client->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    MESSAGE lo_exception->get_text( ) TYPE 'E'.
    RETURN.
ENDTRY.

Сохраните и активируйте отчет.
Выполнить отчет (F8).

При успешном выполнении вы должны увидеть отчет, как показано ниже:

7. Опубликовать сообщение в теме

Теперь, когда тема готова к запуску, мы можем сосредоточиться на отправке данных. Далее научимся публиковать сообщения в этой теме. Сообщения публикуются в теме с помощью метода PUBLISH_TOPICS заглушки API /GOOG/CL_PUBSUB_V1 .

Сигнатура метода:

В графическом интерфейсе SAP введите код транзакции SE38.
Создайте отчет с именем ZPUBSUB_DEMO_PUBLISH .
В открывшемся всплывающем окне введите данные, как показано ниже, и нажмите кнопку «Сохранить».

В следующем всплывающем окне выберите Локальный объект или укажите имя пакета, если необходимо.
В редакторе ABAP добавьте следующий код:

" Data Declaration
DATA:
  lo_client        TYPE REF TO /goog/cl_pubsub_v1,
  ls_message       TYPE /goog/cl_pubsub_v1=>ty_025,
  ls_input         TYPE /goog/cl_pubsub_v1=>ty_023.

TRY.
    " Open HTTP Connection
    CREATE OBJECT lo_client EXPORTING iv_key_name = 'PUBSUB_DEMO'.

    " Populate relevant parameters
    DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
    DATA(lv_p_topics_id) = CONV string( 'PUBSUB_DEMO_TOPIC' ).

    ls_message-data = cl_http_utility=>encode_base64( unencoded = ' This message was published to topic' ).
    APPEND ls_message TO ls_input-messages.

    " Call API method : pubsub.topics.publish
    " This method publishes the message(encoded in base64 format to the topic )
    lo_client->publish_topics(
     EXPORTING
       iv_p_projects_id = lv_p_projects_id
       iv_p_topics_id   = lv_p_topics_id
       is_input         = ls_input
     IMPORTING
       es_output        = DATA(ls_output)
       ev_ret_code      = DATA(lv_ret_code)
       ev_err_text      = DATA(lv_err_text)
       es_err_resp      = DATA(ls_err_resp)  ).

    IF lo_client->is_success( lv_ret_code ) = abap_true.
       DATA(lv_msg) = 'Message was published to topic '  && ': ' &&         lv_p_topics_id.
      MESSAGE lv_msg TYPE 'I' DISPLAY LIKE 'S'.

    ELSE.
      MESSAGE lv_err_text TYPE 'E'.
    ENDIF.

    " Close HTTP Connection
    lo_client->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    MESSAGE lv_err_text TYPE 'E'.
    RETURN.
ENDTRY.

Сохраните и активируйте отчет.
Выполнить отчет (F8).

При успешном выполнении вы должны увидеть отчет, как показано ниже:

8. Поздравления

Поздравляем! Вы успешно опубликовали сообщение в API Pub/Sub Google Cloud Platform, используя ABAP SDK для Google Cloud.

Теперь вы можете приступить к выполнению приведенной ниже лабораторной работы, чтобы продолжить обучение использованию ABAP SDK для доступа к различным облачным сервисам Google.

Получите событие из Cloud Pub/Sub
Загрузка файла в облачное хранилище с разделением на фрагменты
Вызовите Vertex AI test-bison из ABAP
. . .

9. Уборка

Если вы не хотите продолжать работу с дополнительными практическими занятиями, связанными с ABAP SDK для Google Cloud, пожалуйста, продолжите очистку.

Удалить проект

Внимание : удаление проекта имеет следующие последствия:

Всё в проекте будет удалено. Если вы использовали существующий проект для задач в этом документе, при его удалении вы также удалите всю остальную работу, выполненную в рамках проекта.
Пользовательские идентификаторы проектов утеряны. При создании этого проекта вы могли создать собственный идентификатор проекта, который захотите использовать в будущем. Чтобы сохранить URL-адреса, использующие этот идентификатор проекта, например URL-адрес appspot.com , удалите выбранные ресурсы внутри проекта, а не весь проект.

Если вы планируете изучить несколько архитектур, учебных пособий или быстрых стартов, повторное использование проектов может помочь вам избежать превышения квот проекта.

Удалить проект Google Cloud:

gcloud projects delete abap-sdk-poc

Удалить отдельные ресурсы

Удалить вычислительный экземпляр:

gcloud compute instances delete abap-trial-docker

Удалить правила брандмауэра:

gcloud compute firewall-rules delete sapmachine

Удалить учетную запись службы:

gcloud iam service-accounts delete \
    abap-sdk-dev@abap-sdk-poc.iam.gserviceaccount.com

Публикация события в Cloud Pub/Sub с помощью ABAP SDK для Google Cloud Оптимизируйте свои подборки Сохраняйте и классифицируйте контент в соответствии со своими настройками.