Ta strona została przetłumaczona przez Cloud Translation API.

Publikowanie zdarzenia w Cloud Pub/Sub za pomocą pakietu SDK ABAP dla Google Cloud

1. Wprowadzenie

W tym samouczku znajdziesz instrukcje publikowania zdarzenia w interfejsie Google Cloud Pub/Sub API za pomocą pakietu ABAP SDK for Google Cloud.

W tym module używane są te usługi Google Cloud:

Pub/Sub
Cloud Shell

Co utworzysz

Dowiesz się:

włączyć Pub/Sub w projekcie Google Cloud,
utworzyć temat Pub/Sub,
publikować wiadomości,

2. Zanim zaczniesz

Na Twoim systemie jest zainstalowany pakiet ABAP SDK for Google Cloud. Aby skonfigurować nowy system, zapoznaj się z samouczkiem Instalowanie wersji próbnej ABAP w Google Cloud Platform.
Używasz Cloud Shell, czyli środowiska wiersza poleceń działającego w Google Cloud. W prawym górnym rogu Cloud Console kliknij Aktywuj Cloud Shell:

Uruchom te polecenia, aby uwierzytelnić się na koncie i ustawić domyślny projekt na abap-sdk-poc. Jako przykładu używamy strefy us-west4-b. W razie potrzeby zmień projekt i strefę w tych poleceniach zgodnie ze swoimi preferencjami.

gcloud auth login
gcloud config set project abap-sdk-poc
gcloud config set compute/zone us-west4-b

3. Przegląd

Ten przewodnik obejmuje te komponenty usługi Pub/Sub:

Publikujący (zwany też producentem): tworzy wiadomości i wysyła (publikuje) je do usługi przesyłania wiadomości w określonym temacie.
Wiadomość: dane przesyłane przez usługę przesyłania wiadomości.
Temat: nazwany podmiot reprezentujący strumień wiadomości.

4. Konfigurowanie usługi Pub/Sub

Aby utworzyć konto usługi z wymaganą rolą, uruchom w terminalu Cloud Shell to polecenie:

gcloud iam service-accounts create abap-sdk-pubsub-tester --display-name="Service Account for PubSub"

Aby włączyć interfejs Pub/Sub API na koncie usługi (abap-sdk-poc), uruchom w terminalu Cloud Shell to polecenie:

gcloud services enable pubsub.googleapis.com

Aby móc utworzyć temat, przypisz do konta usługi rolę uprawnień pubsub.topics.create. Uruchom w terminalu Cloud Shell to polecenie:

gcloud endpoints services add-iam-policy-binding pubsub.googleapis.com \ --member='serviceAccount:abap-sdk-pubusb-tester@abap-sdk-poc.iam.gserviceaccount.com' \
--role='roles/roles/pubsub.topics.create'

Aby móc publikować komunikaty w temacie, przypisz do konta usługi rolę uprawnień pubsub.topics.publish. Uruchom w terminalu Cloud Shell to polecenie:

gcloud endpoints services add-iam-policy-binding pubsub.googleapis.com \ --member='serviceAccount:abap-sdk-pubusb-tester@abap-sdk-poc.iam.gserviceaccount.com' \
--role='roles/roles/pubsub.topics.publish'

Aby sprawdzić, czy role zostały dodane, otwórz stronę IAM. Utworzone konto usługi powinno być widoczne wraz z przypisanymi do niego rolami.

5. Konfigurowanie klucza klienta

Aby zachować konfigurację w tabeli /GOOG/CLIENT_KEY, wykonaj te czynności:

W SAP GUI wpisz kod transakcji SPRO.
Kliknij SAP Reference IMG (SAP Reference IMG).
Kliknij ABAP SDK for Google Cloud > Ustawienia podstawowe > Skonfiguruj klucz klienta.
Kliknij Nowe wpisy.
Wpisz wartości w tych polach:

Pole	Opis
Nazwa klucza Google Cloud	PUBSUB_DEMO
Nazwa konta usługi Google Cloud	abap-sdk-dev@abap-sdk-poc.iam.gserviceaccount.com
Zakres Google Cloud	https://www.googleapis.com/auth/cloud-platform
Identyfikator projektu Google Cloud	abap-sdk-poc
Klasa autoryzacji	/GOOG/CL_AUTH_GOOGLE

Pozostaw pozostałe pola puste.

6. Tworzenie tematu

Temat tworzysz za pomocą metody CREATE_TOPICS w stubie interfejsu API /GOOG/CL_PUBSUB_V1. Sygnatura metody:

W SAP GUI wpisz kod transakcji SE38.
Utwórz raport o nazwie ZPUBSUB_DEMO.
W wyświetlonym okienku podaj szczegóły jak poniżej i kliknij Zapisz.

W następnym wyskakującym okienku wybierz Local Object (Obiekt lokalny) lub podaj nazwę pakietu.
W edytorze ABAP dodaj ten kod:

" Data Declaration
DATA:
  lo_client        TYPE REF TO /goog/cl_pubsub_v1.

TRY.
    " Open HTTP Connection
    CREATE OBJECT lo_client EXPORTING iv_key_name = 'PUBSUB_DEMO'.

    " Populate relevant parameters
    DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
    DATA(lv_p_topics_id) = CONV string( 'PUBSUB_DEMO_TOPIC' ).

    " Call API method pubsub.topics.create
    lo_client->create_topics(
      EXPORTING
        iv_p_projects_id = lv_p_projects_id
        iv_p_topics_id   = lv_p_topics_id
      IMPORTING
      es_output        = DATA(ls_output)
      ev_ret_code      = DATA(lv_ret_code)
      ev_err_text      = DATA(lv_err_text)
      es_err_resp      = DATA(ls_err_resp) ).

    IF lo_client->is_success( lv_ret_code ) = abap_true.
      DATA(lv_msg) = 'Topic ' && ':' && lv_p_topics_id && ' was created!'.
      MESSAGE lv_msg TYPE 'I' .
    ELSE.
      MESSAGE lv_err_text TYPE 'E'.
    ENDIF.

    " Close HTTP Connection
    lo_client->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    MESSAGE lo_exception->get_text( ) TYPE 'E'.
    RETURN.
ENDTRY.

Zapisz i aktywuj raport.
Wykonaj raport (F8).

Po pomyślnym wykonaniu powinien wyświetlić się raport podobny do tego:

7. Publikowanie wiadomości w temacie

Temat jest gotowy, więc możemy teraz skupić się na wysyłaniu do niego danych. Teraz dowiesz się, jak publikować wiadomości w tym temacie. Wiadomości są publikowane w temacie za pomocą metody PUBLISH_TOPICS z pliku stub interfejsu API /GOOG/CL_PUBSUB_V1.

Sygnatura metody:

W interfejsie SAP GUI wpisz kod transakcji SE38.
Utwórz raport o nazwie ZPUBSUB_DEMO_PUBLISH.
W wyświetlonym okienku podaj szczegóły jak poniżej i kliknij Zapisz.

W następnym wyskakującym okienku wybierz Local Object (Obiekt lokalny) lub podaj nazwę pakietu.
W edytorze ABAP dodaj ten kod:

" Data Declaration
DATA:
  lo_client        TYPE REF TO /goog/cl_pubsub_v1,
  ls_message       TYPE /goog/cl_pubsub_v1=>ty_025,
  ls_input         TYPE /goog/cl_pubsub_v1=>ty_023.

TRY.
    " Open HTTP Connection
    CREATE OBJECT lo_client EXPORTING iv_key_name = 'PUBSUB_DEMO'.

    " Populate relevant parameters
    DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
    DATA(lv_p_topics_id) = CONV string( 'PUBSUB_DEMO_TOPIC' ).

    ls_message-data = cl_http_utility=>encode_base64( unencoded = ' This message was published to topic' ).
    APPEND ls_message TO ls_input-messages.

    " Call API method : pubsub.topics.publish
    " This method publishes the message(encoded in base64 format to the topic )
    lo_client->publish_topics(
     EXPORTING
       iv_p_projects_id = lv_p_projects_id
       iv_p_topics_id   = lv_p_topics_id
       is_input         = ls_input
     IMPORTING
       es_output        = DATA(ls_output)
       ev_ret_code      = DATA(lv_ret_code)
       ev_err_text      = DATA(lv_err_text)
       es_err_resp      = DATA(ls_err_resp)  ).

    IF lo_client->is_success( lv_ret_code ) = abap_true.
       DATA(lv_msg) = 'Message was published to topic '  && ': ' &&         lv_p_topics_id.
      MESSAGE lv_msg TYPE 'I' DISPLAY LIKE 'S'.

    ELSE.
      MESSAGE lv_err_text TYPE 'E'.
    ENDIF.

    " Close HTTP Connection
    lo_client->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    MESSAGE lv_err_text TYPE 'E'.
    RETURN.
ENDTRY.

Zapisz i aktywuj raport.
Wykonaj raport (F8).

Po pomyślnym wykonaniu powinien wyświetlić się raport podobny do tego:

8. Gratulacje

Gratulacje! Udało Ci się opublikować wiadomość w interfejsie Pub/Sub API Google Cloud Platform za pomocą pakietu ABAP SDK for Google Cloud.

Możesz teraz przejść do poniższych ćwiczeń z programowania, aby kontynuować naukę korzystania z pakietu ABAP SDK w celu uzyskiwania dostępu do różnych usług Google Cloud.

Otrzymywanie zdarzenia z Cloud Pub/Sub
Przesyłanie pliku do zasobnika Cloud Storage z podziałem na części
Wywoływanie funkcji test-bison w Vertex AI z ABAP
. . .

9. Czyszczenie danych

Jeśli nie chcesz kontynuować pracy z dodatkowymi ćwiczeniami dotyczącymi pakietu ABAP SDK do Google Cloud, przejdź do sekcji czyszczenia.

Usuwanie projektu

Uwaga: usunięcie projektu spowoduje, że:

Wszystkie dane projektu zostaną usunięte. Jeśli do wykonania zadań opisanych w tym dokumencie użyto istniejącego projektu, po jego usunięciu usuniesz też wszystkie inne wykonane w nim czynności.
Niestandardowe identyfikatory projektu zostaną utracone. Podczas tworzenia tego projektu możesz utworzyć niestandardowy identyfikator projektu, którego chcesz używać w przyszłości. Aby zachować adresy URL, które używają identyfikatora projektu, np. adres URL appspot.com, usuń wybrane zasoby w projekcie zamiast usuwać cały projekt.

Jeśli zamierzasz skorzystać z różnych architektur, samouczków lub krótkich wprowadzeń, ponowne wykorzystanie tych samych projektów może pomóc Ci uniknąć przekroczenia limitów związanych z projektami.

Usuń projekt Google Cloud:

gcloud projects delete abap-sdk-poc

Usuwanie poszczególnych zasobów

Usuń instancję obliczeniową:

gcloud compute instances delete abap-trial-docker

Usuń reguły zapory sieciowej:

gcloud compute firewall-rules delete sapmachine

Usuń konto usługi:

gcloud iam service-accounts delete \
    abap-sdk-dev@abap-sdk-poc.iam.gserviceaccount.com

Publikowanie zdarzenia w Cloud Pub/Sub za pomocą pakietu SDK ABAP dla Google Cloud Zadbaj o dobrą organizację dzięki kolekcji Zapisuj i kategoryzuj treści zgodnie ze swoimi preferencjami.